Browser

Asks a mobile device for the numeric keypad instead of the full keyboard (keyboard_set_mode) on an Input.

Z2UI5_CL_SMP_APP_352

Learn Browser UI5 1.71

The facts

Repository: abap2UI5/samples
Class: Z2UI5_CL_SMP_APP_352
Source file: z2ui5_cl_smp_app_352.clas.abap ↗
Category: Browser
Learning path: Reach outside the view
Minimum UI5: 1.71 — the floor abap2UI5 holds its samples to
In the playground: runs in the browser, with no system and nothing installed
Documentation: abap2ui5.github.io/docs/cookbook/browser_interaction/soft_k… ↗

Keywords: mobile, numeric, keypad, keyboard_set_mode, phone, input

Controls it builds

Read out of the builder chain by the abap2UI5 linter, not from the category this sample is filed under — which is what makes “which samples build one of these” a question the catalogue can answer at all.

Libraries

Run it here

The sample running, in this page — the app on its own, with no editor over it. Switch to Playground with this code

Nothing is installed and nothing is sent anywhere: the ABAP is compiled to JavaScript in this browser and runs against abap2UI5 itself.

The ABAP

z2ui5_cl_smp_app_352.clas.abap — 96 lines Read it on GitHub ↗

" @keywords mobile numeric keypad keyboard_set_mode phone input
" @summary Asks a mobile device for the numeric keypad instead of the full keyboard (keyboard_set_mode) on an Input.
" @docs https://abap2ui5.github.io/docs/cookbook/browser_interaction/soft_keyboard
CLASS z2ui5_cl_smp_app_352 DEFINITION PUBLIC.

  PUBLIC SECTION.
    INTERFACES z2ui5_if_app.

    DATA input TYPE string.

  PROTECTED SECTION.
    DATA client TYPE REF TO z2ui5_if_client.

    METHODS view_display.
    METHODS on_event.

  PRIVATE SECTION.
ENDCLASS.


CLASS z2ui5_cl_smp_app_352 IMPLEMENTATION.


  METHOD z2ui5_if_app~main.

    me->client = client.

    IF client->check_on_init( ).
      view_display( ).
      client->follow_up_action(
          val   = z2ui5_if_client=>cs_event-set_focus
          t_arg = VALUE #( ( `ZINPUT` ) ) ).
      client->follow_up_action(
          val   = z2ui5_if_client=>cs_event-keyboard_set_mode
          t_arg = VALUE #( ( `ZINPUT` ) ( `numeric` ) ) ).
    ELSEIF client->check_on_navigated( ).
      view_display( ).
    ENDIF.

    on_event( ).

  ENDMETHOD.


  METHOD view_display.

    DATA(view) = z2ui5_cl_ui5_view_builder=>factory(
        )->ele( n = `View` ns = `mvc`
            )->a( n = `displayBlock` v = `true`
            )->a( n = `height`       v = `100%`
            )->a( n = `xmlns`        v = `sap.m`
            )->a( n = `xmlns:mvc`    v = `sap.ui.core.mvc`
            )->a( n = `xmlns:core`   v = `sap.ui.core`
            )->a( n = `xmlns:form`   v = `sap.ui.layout.form` ).

    DATA(page) = view->ele( `Shell`
        )->ele( `Page`
            )->a( n = `title`          v = `abap2UI5 - Browser - Soft Keyboard Mode on Mobile`
            )->a( n = `showNavButton`  b = client->check_app_prev_stack( )
            )->a( n = `navButtonPress` v = client->_event_nav_app_leave( ) ).

    page->tag( `MessageStrip`
        )->a( n = `text`     v = `Set the on-screen soft keyboard mode (numeric or off) via the keyboard_set_mode follow-up action, and ` &&
                   `focus the input on load.`
        )->a( n = `type`     v = `Information`
        )->a( n = `showIcon` b = abap_true
        )->a( n = `class`    v = `sapUiSmallMargin` ).

    page->ele( n = `SimpleForm` ns = `form`
        )->a( n = `editable` b = abap_true
        )->ele( n = `content` ns = `form`
            )->tag( `Title`
                )->a( n = `text` v = `Keyboard on/off`
            )->tag( `Label`
                )->a( n = `text` v = `Input (numeric keyboard)`
            )->tag( `Input`
                )->a( n = `id`               v = `ZINPUT`
                )->a( n = `value`            v = client->_bind( input )
                )->a( n = `valueHelpRequest` v = client->_event( `CALL_KEYBOARD` )
                )->a( n = `showValueHelp`    b = abap_true ).

    client->view_display( page->stringify( ) ).

  ENDMETHOD.


  METHOD on_event.

    IF client->check_on_event( `CALL_KEYBOARD` ).
      client->follow_up_action(
          val   = z2ui5_if_client=>cs_event-keyboard_set_mode
          t_arg = VALUE #( ( `ZINPUT` ) ( `none` ) ) ).
    ENDIF.

  ENDMETHOD.
ENDCLASS.